Mysql.xcsm

浏览该文件的文档.

//xlang Source, Name:Mysql.xcsm
//Date: Tue Jul 16:06:32 2019
 
class Mysql : Sql.Connection {
    public static const int  CLIENT_LONG_PASSWORD   = 1;    /* new more secure passwords */
    public static const int  CLIENT_FOUND_ROWS  = 2;    /* Found instead of affected rows */
    public static const int  CLIENT_LONG_FLAG   = 4;    /* Get all column flags */
    public static const int  CLIENT_CONNECT_WITH_DB = 8;    /* One can specify db on connect */
    public static const int  CLIENT_NO_SCHEMA   = 16;   /* Don't allow database.table.column */
    public static const int  CLIENT_COMPRESS    =   32; /* Can use compression protocol */
    public static const int  CLIENT_ODBC        = 64;   /* Odbc client */
    public static const int  CLIENT_LOCAL_FILES = 128;  /* Can use LOAD DATA LOCAL */
    public static const int  CLIENT_IGNORE_SPACE    = 256;  /* Ignore spaces before '(' */
    public static const int  CLIENT_PROTOCOL_41 = 512;  /* New 4.1 protocol */
    public static const int  CLIENT_INTERACTIVE = 1024; /* This is an interactive client */
    public static const int  CLIENT_SSL              = 2048;    /* Switch to SSL after handshake */
    public static const int  CLIENT_IGNORE_SIGPIPE   = 4096;    /* IGNORE sigpipes */
    public static const int  CLIENT_TRANSACTIONS    = 8192; /* Client knows about transactions */
    public static const int  CLIENT_RESERVED         = 16384;   /* Old flag for 4.1 protocol  */
    public static const int  CLIENT_RESERVED2        = 32768;   /* Old flag for 4.1 authentication */
    public static const int  CLIENT_MULTI_STATEMENTS = (1 << 16); /* Enable/disable multi-stmt support */
    public static const int  CLIENT_MULTI_RESULTS    = (1 << 17); /* Enable/disable multi-results */
    public static const int  CLIENT_PS_MULTI_RESULTS = (1 << 18); /* Multi-results in PS-protocol */
 
    public static const int  CLIENT_PLUGIN_AUTH = (1 << 19); /* Client supports plugin authentication */
    public static const int  CLIENT_CONNECT_ATTRS = (1 << 20); /* Client supports connection attributes */
 
    /* Enable authentication response packet to be larger than 255 bytes. */
    public static const int  CLIENT_PLUGIN_AUTH_LENENC_CLIENT_DATA = (1 << 21);
 
    /* Don't close the connection for a connection with expired password. */
    public static const int  CLIENT_CAN_HANDLE_EXPIRED_PASSWORDS = (1 << 22);
 
    public static const int  CLIENT_SESSION_TRACK = (1 << 23);
    /* Client no longer needs EOF packet */
    public static const int  CLIENT_DEPRECATE_EOF = (1 << 24);
 
    public static const int  CLIENT_SSL_VERIFY_SERVER_CERT = (1 << 30);
    public static const int  CLIENT_REMEMBER_OPTIONS = (1 << 31);
 
 
 
    /* Gather all possible capabilites (flags) supported by the server */
    public static const int  CLIENT_ALL_FLAGS = (CLIENT_LONG_PASSWORD
            | CLIENT_FOUND_ROWS
            | CLIENT_LONG_FLAG
            | CLIENT_CONNECT_WITH_DB
            | CLIENT_NO_SCHEMA
            | CLIENT_COMPRESS
            | CLIENT_ODBC
            | CLIENT_LOCAL_FILES
            | CLIENT_IGNORE_SPACE
            | CLIENT_PROTOCOL_41
            | CLIENT_INTERACTIVE
            | CLIENT_SSL
            | CLIENT_IGNORE_SIGPIPE
            | CLIENT_TRANSACTIONS
            | CLIENT_RESERVED
            | CLIENT_RESERVED2
            | CLIENT_MULTI_STATEMENTS
            | CLIENT_MULTI_RESULTS
            | CLIENT_PS_MULTI_RESULTS
            | CLIENT_SSL_VERIFY_SERVER_CERT
            | CLIENT_REMEMBER_OPTIONS
            | CLIENT_PLUGIN_AUTH
            | CLIENT_CONNECT_ATTRS
            | CLIENT_PLUGIN_AUTH_LENENC_CLIENT_DATA
            | CLIENT_CAN_HANDLE_EXPIRED_PASSWORDS
            | CLIENT_SESSION_TRACK
            | CLIENT_DEPRECATE_EOF
                                                );
 
    /*
      Switch off the flags that are optional and depending on build flags
      If any of the optional flags is supported by the build it will be switched
      on before sending to the client during the connection handshake.
    */
    public static const int CLIENT_BASIC_FLAGS = ( ( (CLIENT_ALL_FLAGS & ~CLIENT_SSL)
            & ~CLIENT_COMPRESS)
            & ~CLIENT_SSL_VERIFY_SERVER_CERT);
 
    static const String DRIVERNAME = "mysql";
    byte [] _mysql ;
 
    int port = 3306;
    int timeout = 0;
    int return_option = MysqlOption.RET_ERRCODE;
    int client_flags = 0;
 
    public enum MysqlOption {
        PORT,
        TIMEOUT,
        CHARSET,
        SELECTDB,
        RET_ERRCODE,
        RET_CHANGES,
        CLIENT_FLAGS
    };
 
    static class MysqlRegister : Sql.ConnectionRegister {
        Sql.Connection allocConnection (String drivername) override {
            if (drivername.equals ("mysql") ) {
                return new Mysql();
            }
 
            return nilptr;
        }
    };
 
    public static bool registry() {
        if (Helper.init() ) {
            Sql.Database.reigstry (DRIVERNAME, new MysqlRegister() );
            return true;
        }
 
        return false;
    }
 
    static class Helper : Library {
        static bool bloaded = false;
 
        public static bool init() {
            if (bloaded == false) {
                try {
                    loadLibrary ("mysql_helper");
                    bloaded = true;
                } catch (Exception e) {
                    _system_.output (e.getMessage() );
                }
            }
 
            return bloaded;
        }
 
        public import {
            Pointer cdecl rs_create (Pointer);
            void cdecl rs_free (Pointer);
            bool cdecl rs_next (Pointer);
            bool cdecl rs_first (Pointer);
            int cdecl rs_label2Index (Pointer, String);
            long cdecl rs_getRowCount (Pointer);
            bool cdecl rs_last (Pointer);
            bool cdecl rs_isValid (Pointer);
            bool cdecl statement_res_isValid (Pointer);
            bool cdecl rs_isLast (Pointer);
            bool cdecl next_statement_res_4x (Pointer);
 
            String cdecl rs_getValue (Pointer, String);
            int cdecl rs_getValueI (Pointer, String);
            long cdecl rs_getValueL (Pointer, String);
            double cdecl rs_getValueD (Pointer, String);
 
            String cdecl rs_getIValue (Pointer, int);
            int cdecl rs_getIValueI (Pointer, int);
            long cdecl rs_getIValueL (Pointer, int);
            double cdecl rs_getIValueD (Pointer, int);
 
            String cdecl stmt_getValue (Pointer, String);
            int cdecl stmt_getValueI (Pointer, String);
            long cdecl stmt_getValueL (Pointer, String);
            double cdecl stmt_getValueD (Pointer, String);
 
            String cdecl stmt_getIValue (Pointer, int);
            int cdecl stmt_getIValueI (Pointer, int);
            long cdecl stmt_getIValueL (Pointer, int);
            double cdecl stmt_getIValueD (Pointer, int);
 
 
            Pointer cdecl x_mysql_init (ObjectPtr );
 
            int cdecl x_mysql_options (ObjectPtr, int option, ObjectPtr );
 
            Pointer cdecl x_mysql_real_connect (ObjectPtr, String host,
                                                String user,
                                                String passwd,
                                                String db,
                                                int port,
                                                String unix_socket,
                                                int clientflag);
 
            int cdecl x_mysql_set_character_set (ObjectPtr, String csname);
 
            int cdecl x_mysql_select_db (ObjectPtr, String db);
            int cdecl stmt_column_type (Pointer, int);
            int cdecl stmt_find_column (Pointer, String key);
            String cdecl stmt_get_column (Pointer, int id);
            long cdecl create_statement_4x (ObjectPtr);
            long cdecl store_statement_res_4x (Pointer);
            long cdecl stmt_row_count (Pointer);
            bool cdecl close_statement_4x (Pointer);
            bool cdecl bind_statement_param_4x (Pointer, int n, ObjectPtr data, int len, int type);
            bool cdecl reset_statement_4x (Pointer);
            int cdecl statement__prepare_4x (Pointer, String sql, int len);
            String cdecl get_statement_error_4x (Pointer);
            long cdecl get_lastinserted_id_4x (ObjectPtr);
            long cdecl get_affected_rows_4x (ObjectPtr);
            long cdecl stmt_lastinserted_id_4x (Pointer);
            long cdecl stmt_affected_rows_4x (Pointer);
            int cdecl statement_execute_4x (Pointer);
 
            int cdecl x_mysql_errno (ObjectPtr );
            String cdecl x_mysql_info (ObjectPtr );
            String cdecl x_mysql_state (ObjectPtr );
            String cdecl x_mysql_error (ObjectPtr );
 
            int cdecl x_mysql_query (ObjectPtr, String );
 
            void cdecl x_mysql_close (ObjectPtr);
 
            Pointer     cdecl x_mysql_store_result (ObjectPtr);
 
            void        cdecl x_mysql_data_seek (Pointer result,
                                                 long offset);
 
            Pointer     cdecl x_mysql_row_seek (Pointer result,
                                                long offset);
 
            Pointer cdecl x_mysql_row_tell (Pointer res);
 
            Pointer cdecl x_mysql_fetch_row (Pointer result);
 
            long cdecl x_mysql_num_rows (Pointer res);
 
            void cdecl x_mysql_free_result (Pointer result);
 
            int cdecl x_mysql_num_fields (Pointer res);
        };
    };
 
    static bool registried = registry();
 
    public static class MysqlResultSet : Sql.ResultSet {
        long hres;
 
        public MysqlResultSet (long r) {
            hres = Helper.rs_create (r);
        }
 
        public bool first() override {
            return Helper.rs_first (hres);
        }
 
        public bool last() override {
            return Helper.rs_last (hres);
        }
 
        public bool next() override {
            return Helper.rs_next (hres);
        }
 
        public bool isEof() override {
            throw new Sql.DatabaseNotSupportException ("isEof");
            return false;
        }
 
        public bool previous() override {
            throw new Sql.DatabaseNotSupportException ("previous");
            return false;
        }
 
        public bool isFirst() override {
            throw new Sql.DatabaseNotSupportException ("isFirst");
            return false;
        }
 
        public bool isLast() override {
            return Helper.rs_isLast (hres);
        }
 
        public bool isValid() override {
            return Helper.rs_isValid (hres);
        }
 
        public int getInt (String columnlabel) override {
            return Helper.rs_getValueI (hres, columnlabel);
        }
 
        public long getLong (String columnlabel) override {
            return Helper.rs_getValueL (hres, columnlabel);
        }
        
        public float getFloat(String columnlabel) override {
            return getString(columnlabel).parseFloat();
        }
        
        public double getDouble (String columnlabel) override {
            return Helper.rs_getValueD (hres, columnlabel);
        }
 
        public byte getByte (String columnlabel) override {
            return Helper.rs_getValueI (hres, columnlabel);
        }
 
        public bool getBoolean (String columnlabel) override {
            return Helper.rs_getValueI (hres, columnlabel) != 0;
        }
 
        public String getString (String columnlabel) override {
            return Helper.rs_getValue (hres, columnlabel);
        }
 
        public int getInt (int columnIndex) override {
            return Helper.rs_getIValueI (hres, columnIndex);
        }
 
        public long getLong (int columnIndex) override {
            return Helper.rs_getIValueL (hres, columnIndex);
        }
 
        public double getDouble (int columnIndex) override {
            return Helper.rs_getIValueD (hres, columnIndex);
        }
        
        public float getFloat(int columnIndex) override {
            return getString(columnIndex).parseFloat();
        }
 
        public byte getByte (int columnIndex) override {
            return Helper.rs_getIValueI (hres, columnIndex);
        }
 
        public bool getBoolean (int columnIndex) override {
            return Helper.rs_getIValueI (hres, columnIndex) != 0;
        }
 
        public String getString (int columnIndex) override {
            return Helper.rs_getIValue (hres, columnIndex);
        }
 
        public int findColumn (String) override {
            throw new Sql.DatabaseNotSupportException ("findColumn");
            return -1;
        }
 
        public String getColumnName (int i) override {
            throw new Sql.DatabaseNotSupportException ("getColumnName");
            return nilptr;
        }
 
        public int getColumnCount() override {
            throw new Sql.DatabaseNotSupportException ("getColumnCount");
            return -1;
        }
 
        public long getRowCount() override {
            return Helper.rs_getRowCount (hres);
        }
 
        public int getRow() override {
            throw new Sql.DatabaseNotSupportException ("getRow");
            return 0;
        }
 
        public void close() override {
            if (hres != 0) {
                Helper.rs_free (hres);
                hres = 0;
            }
        }
 
        void finalize() {
            close();
        }
    };
 
    public static class MysqlStatement : Sql.Statement {
        Mysql mysql;
 
        public MysqlStatement (Mysql m) {
            mysql = m;
        }
 
        public int execute (String sql) override {
            if (0 != Helper.x_mysql_query (mysql._mysql, sql) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), mysql.getError() );
            }
 
            if (mysql.return_option == MysqlOption.RET_CHANGES) {
                return Helper.get_affected_rows_4x (mysql._mysql);
            }
 
            return 0;
        }
 
        public Sql.ResultSet executeQuery (String sql) override {
            if (0 != Helper.x_mysql_query (mysql._mysql, sql) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), mysql.getError() );
            }
 
            return getResult();
        }
 
        public int executeUpdate (String sql) override {
            if (0 != Helper.x_mysql_query (mysql._mysql, sql) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), mysql.getError() );
            }
 
            if (mysql.return_option == MysqlOption.RET_CHANGES) {
                return Helper.get_affected_rows_4x (mysql._mysql);
            }
 
            return 0;
        }
 
        public Sql.ResultSet getResult() override {
            long res = Helper.x_mysql_store_result (mysql._mysql);
 
            if (res != 0) {
                return new MysqlResultSet (res);
            }
 
            return nilptr;
        }
 
        public int get_changes() override {
            return Helper.get_affected_rows_4x (mysql._mysql);
        }
 
        public int get_lastInsertId() override {
            return Helper.get_lastinserted_id_4x (mysql._mysql);
        }
 
        public void close() override {
 
        }
    };
 
 
 
    public static class MysqlPreparedResultSet : Sql.ResultSet {
        long hres;
        Mysql.MysqlPreparedStatement stmt;
        int field_count = 0;
        public MysqlPreparedResultSet (Mysql.MysqlPreparedStatement _stmt, long r) {
            stmt = _stmt;
            hres = r;
            field_count = Helper.store_statement_res_4x (r);
        }
 
        public bool first() override {
            throw new Sql.DatabaseNotSupportException ("first");
            return false;
        }
 
        public bool last() override {
            throw new Sql.DatabaseNotSupportException ("last");
            return false;
        }
 
        public bool next() override {
            return Helper.next_statement_res_4x (hres);
        }
 
        public bool isEof() override {
            throw new Sql.DatabaseNotSupportException ("isEof");
            return false;
        }
 
        public bool previous() override {
            throw new Sql.DatabaseNotSupportException ("previous");
            return false;
        }
 
        public bool isFirst() override {
            throw new Sql.DatabaseNotSupportException ("isFirst");
            return false;
        }
 
        public bool isLast() override {
            throw new Sql.DatabaseNotSupportException ("isLast");
            return false;
        }
 
        public bool isValid() override {
            return Helper.rs_isValid (hres);
        }
 
        public int getInt (String columnlabel) override {
            return Helper.stmt_getValueI (hres, columnlabel);
        }
 
        public long getLong (String columnlabel) override {
            return Helper.stmt_getValueL (hres, columnlabel);
        }
        
        public float getFloat(String columnlabel) override {
            return getString(columnlabel).parseFloat();
        }
 
        public double getDouble (String columnlabel) override {
            return Helper.stmt_getValueD (hres, columnlabel);
        }
 
        public byte getByte (String columnlabel) override {
            return Helper.stmt_getValueI (hres, columnlabel);
        }
 
        public bool getBoolean (String columnlabel) override {
            return Helper.stmt_getValueI (hres, columnlabel) != 0;
        }
 
        public String getString (String columnlabel) override {
            return Helper.stmt_getValue (hres, columnlabel);
        }
 
        public int getInt (int columnIndex) override {
            return Helper.stmt_getIValueI (hres, columnIndex);
        }
 
        public long getLong (int columnIndex) override {
            return Helper.stmt_getIValueL (hres, columnIndex);
        }
        
        public float getFloat(int columnIndex) override {
            return getString(columnIndex).parseFloat();
        }
 
        public double getDouble (int columnIndex) override {
            return Helper.stmt_getIValueD (hres, columnIndex);
        }
 
        public byte getByte (int columnIndex) override {
            return Helper.stmt_getIValueI (hres, columnIndex);
        }
 
        public bool getBoolean (int columnIndex) override {
            return Helper.stmt_getIValueI (hres, columnIndex) != 0;
        }
 
        public String getString (int columnIndex) override {
            return Helper.stmt_getIValue (hres, columnIndex);
        }
 
        public int findColumn (String name) override {
            return Helper.stmt_find_column (hres, name);
        }
 
        public String getColumnName (int i) override {
            return Helper.stmt_get_column (hres, i - 1);
        }
 
        public int getColumnCount() override {
            return field_count;
        }
 
        public long getRowCount() override {
            return Helper.stmt_row_count (hres);
        }
 
        public int getRow() override {
            throw new Sql.DatabaseNotSupportException ("getRow");
            return 0;
        }
 
        public void close() override {
            if (stmt != nilptr) {
                stmt = nilptr;
                hres = 0;
            }
        }
 
        public int getColumnType (int id) override {
            if (id > 0 && id < (field_count + 1) ) {
                return Helper.stmt_column_type (hres, id - 1);
            } else {
                throw new Sql.SqlException (-1, "out of argc ");
            }
 
            return 0;
        }
 
        void finalize() {
            close();
        }
    };
 
    public class MysqlPreparedStatement : Sql.PreparedStatement {
        Mysql mysql;
        long hprepare_handle = 0;
        int param_index = 0;
 
        int argc = 0;
        public MysqlPreparedStatement (Mysql m, String sql) {
            mysql = m;
            hprepare_handle = Helper.create_statement_4x (m._mysql);
 
            if (hprepare_handle != 0) {
                argc = Helper.statement__prepare_4x (hprepare_handle, sql, sql.length() );
 
            } else {
                throw new Sql.SqlException (mysql.getErrorCode(), mysql.getError() );
            }
        }
        public int execute() override {
            if (0 != Helper.statement_execute_4x (hprepare_handle) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), Helper.get_statement_error_4x (hprepare_handle) );
            }
 
            if (mysql.return_option == MysqlOption.RET_CHANGES) {
                return Helper.stmt_affected_rows_4x (hprepare_handle);
            }
 
            return 0;
        }
 
        public Sql.ResultSet executeQuery() override {
            if (0 != Helper.statement_execute_4x (hprepare_handle) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), Helper.get_statement_error_4x (hprepare_handle) );
            }
 
            return new MysqlPreparedResultSet (this, hprepare_handle);
        }
 
        public int execute (String sql) override {
            if (0 != Helper.x_mysql_query (mysql._mysql, sql) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), mysql.getError() );
            }
 
            if (mysql.return_option == MysqlOption.RET_CHANGES) {
                return Helper.get_affected_rows_4x (mysql._mysql);
            }
 
            return 0;
        }
 
        public Sql.ResultSet executeQuery (String sql) override {
            if (0 != Helper.x_mysql_query (mysql._mysql, sql) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), mysql.getError() );
            }
 
            return getResult();
        }
        public int executeUpdate() override {
            if (0 != Helper.statement_execute_4x (hprepare_handle) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), Helper.get_statement_error_4x (hprepare_handle) );
            }
 
            if (mysql.return_option == MysqlOption.RET_CHANGES) {
                return Helper.stmt_affected_rows_4x (hprepare_handle);
            }
 
            return 0;
        }
        public int executeUpdate (String sql) override {
            if (0 != Helper.x_mysql_query (mysql._mysql, sql) ) {
                throw new Sql.SqlException (mysql.getErrorCode(), mysql.getError() );
            }
 
            if (mysql.return_option == MysqlOption.RET_CHANGES) {
                return Helper.get_affected_rows_4x (mysql._mysql);
            }
 
            return 0;
        }
 
        public Sql.ResultSet getResult() override {
            long res = Helper.x_mysql_store_result (mysql._mysql);
 
            if (res != 0) {
                return new MysqlResultSet (res);
            }
 
            return nilptr;
        }
 
        public void setValue (String value) override {
            if (param_index < argc) {
                if (value == nilptr) {
                    if (!Helper.bind_statement_param_4x (hprepare_handle, param_index++, value, 0, 0xf) ) {
                        throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                    }
                } else {
                    if (!Helper.bind_statement_param_4x (hprepare_handle, param_index++, value, value.length(), 0) ) {
                        throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                    }
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
        public void setValue (int value) override {
            if (param_index < argc) {
                if (!Helper.bind_statement_param_4x (hprepare_handle, param_index++, value, 0, 1) ) {
                    throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
        public void setValue (long value) override {
            if (param_index < argc) {
                if (!Helper.bind_statement_param_4x (hprepare_handle, param_index++, value, 0, 2) ) {
                    throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
        public void setValue (byte value) override {
            if (param_index < argc) {
                if (!Helper.bind_statement_param_4x (hprepare_handle, param_index++, value, 0, 3) ) {
                    throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
        public void setValue (double value) override {
            if (param_index < argc) {
                if (!Helper.bind_statement_param_4x (hprepare_handle, param_index++, value, 0, 4) ) {
                    throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
 
        public void setValue (int id, String value) override {
            if (id > 0 && id < (argc + 1) ) {
                if (value == nilptr) {
                    if (!Helper.bind_statement_param_4x (hprepare_handle, id - 1, nilptr, 0, 0xf) ) {
                        throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                    }
                } else {
                    if (!Helper.bind_statement_param_4x (hprepare_handle, id - 1, value, value.length(), 0) ) {
                        throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                    }
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
        public void setValue (int id, int value) override {
            if (id > 0 && id < (argc + 1) ) {
                if (!Helper.bind_statement_param_4x (hprepare_handle, id - 1, value, 0, 1) ) {
                    throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
        public void setValue (int id, long value) override {
            if (id > 0 && id < (argc + 1) ) {
                if (!Helper.bind_statement_param_4x (hprepare_handle, id - 1, value, 0, 2) ) {
                    throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
        public void setValue (int id, byte value) override {
            if (id > 0 && id < (argc + 1) ) {
                if (!Helper.bind_statement_param_4x (hprepare_handle, id - 1, value, 0, 3) ) {
                    throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
        public void setValue (int id, double value) override {
            if (id > 0 && id < (argc + 1) ) {
                if (!Helper.bind_statement_param_4x (hprepare_handle, id - 1, value, 0, 4) ) {
                    throw new Sql.SqlException (-1, Helper.get_statement_error_4x (hprepare_handle) );
                }
            } else {
                throw new Sql.SqlException (-1, "out of argc value:" + value);
            }
        }
 
 
        public void setValues (Object [] args) override {
            for (int i = 0; i < args.length; i++) {
                if (args[i] == nilptr) {
                    setValue ( (String) nilptr);
                } else if (args[i].instanceOf (String) ) {
                    setValue ( (String) args[i]);
                } else if (args[i].instanceOf (int) ) {
                    setValue ( (int) args[i]);
                } else if (args[i].instanceOf (long) ) {
                    setValue ( (long) args[i]);
                } else if (args[i].instanceOf (byte) ) {
                    setValue ( (byte) args[i]);
                } else if (args[i].instanceOf (double) ) {
                    setValue ( (double) args[i]);
                } else {
                    throw new Sql.SqlException (-1, "sql unknow type:" + i);
                }
            }
        }
 
        public int get_changes() override {
            return Helper.stmt_affected_rows_4x (hprepare_handle);
        }
 
        public int get_lastInsertId() override {
            return Helper.stmt_lastinserted_id_4x (hprepare_handle);
        }
 
        public void close() override {
            if (hprepare_handle != 0) {
                Helper.close_statement_4x (hprepare_handle);
                hprepare_handle = 0;
            }
        }
    };
 
 
    public void close() override {
        //TODO:
        if (_mysql != nilptr) {
            Helper.x_mysql_close (_mysql);
            _mysql = nilptr;
        }
    }
 
    void finalize() {
        close();
    }
 
    public void create (String uri, String username, String pwd) override {
        //TODO:
        byte [] __mysql = new byte[2048];
 
 
        if (0l == Helper.x_mysql_init (__mysql) ) {
            throw new Sql.SqlException (Helper.x_mysql_errno (__mysql), Helper.x_mysql_error (__mysql) );
        }
 
        if (timeout != 0) {
            if (0 == Helper.x_mysql_options (__mysql, 0, timeout) ) {
                throw new Sql.SqlException (Helper.x_mysql_errno (__mysql), Helper.x_mysql_error (__mysql) );
            }
        }
 
        if (0l == Helper.x_mysql_real_connect (__mysql, uri, username, pwd, nilptr, port, nilptr, client_flags) ) {
            throw new Sql.SqlException (Helper.x_mysql_errno (__mysql), Helper.x_mysql_error (__mysql) );
        }
 
        _mysql = __mysql;
    }
 
    public bool isClosed() override {
        //TODO:
        return _mysql != nilptr;
    }
 
 
    public int getErrorCode() override {
        return Helper.x_mysql_errno (_mysql);
    }
 
    public String getError() override {
        return Helper.x_mysql_error (_mysql);
    }
 
    public String getSqlState() {
        return Helper.x_mysql_state (_mysql);
    }
 
    public String getInfo() {
        return Helper.x_mysql_info (_mysql);
    }
 
    public Object getOption (int opt) override {
        //TODO:
        throw new Sql.DatabaseNotSupportException ("getOption");
        return nilptr;
    }
 
    public void setOption (int opt, Object option) override {
        switch (opt) {
        case MysqlOption.PORT:
            port = (int) option;
            break;
 
        case MysqlOption.TIMEOUT:
            timeout = (int) option;
            break;
 
        case MysqlOption.CHARSET:
            if (_mysql == nilptr) {
                throw new Sql.SqlException (-1, "mysql not connected!");
            }
 
            if (0 != Helper.x_mysql_set_character_set (_mysql, (String) option) ) {
                throw new Sql.SqlException (Helper.x_mysql_errno (_mysql), Helper.x_mysql_error (_mysql) );
            }
 
            break;
 
        case MysqlOption.SELECTDB:
            if (_mysql == nilptr) {
                throw new Sql.SqlException (-1, "mysql not connected!");
            }
 
            if (0 != Helper.x_mysql_select_db (_mysql, (String) option) ) {
                throw new Sql.SqlException (Helper.x_mysql_errno (_mysql), Helper.x_mysql_error (_mysql) );
            }
 
            break;
 
        case MysqlOption.RET_ERRCODE:
            return_option = MysqlOption.RET_ERRCODE;
            break;
 
        case MysqlOption.RET_CHANGES:
            return_option = MysqlOption.RET_CHANGES;
            break;
 
        case MysqlOption.CLIENT_FLAGS:
            client_flags = (int) option;
            break;
 
        default:
            throw new Sql.DatabaseNotSupportException ("setOption:" + opt);
            break;
        }
    }
 
    public Sql.Statement createStatement() override {
        return new MysqlStatement (this);
    }
 
    public Sql.PreparedStatement prepareStatement (String sql) override {
        return new MysqlPreparedStatement (this, sql);
    }
 
 
};